home *** CD-ROM | disk | FTP | other *** search
/ Gekkan Dennou Club 140 / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan).7z / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan) (Track 1).bin / tools / xpicw / xpicw110.lzh / WLSource / dol.s < prev    next >
Text File  |  1997-04-10  |  2KB  |  130 lines
  1. *    dol.s    Dot OverLap
  2. *        ドットのオーバーラップ / 最高速 = 4
  3. *            by Mitsuky
  4.  
  5.  
  6. SPEED_MAX    equ    4
  7.  
  8.     .offset    8        * 引き数
  9. _source_ptr:    .ds.l    1
  10. _dest_ptr:    .ds.l    1
  11. _speed:        .ds.l    1
  12. _vdisp:        .ds.l    1
  13.  
  14.  
  15.  
  16.     .text
  17.     .even
  18.  
  19.     .dc.b    'WL10',$0d,$0a
  20.     .dc.b    'ドットのオーバーラップ / 最高速 = 4',$0d,$0a
  21.     .dc.b    '    by Mitsuky',$0d,$0a
  22.     .dc.b    $1a
  23.     .even
  24.  
  25. dol:
  26.     link    a6,#0
  27.     movem.l    d1-d7/a0-a5,-(sp)
  28.  
  29.     move.l    _speed(a6),d0
  30.     bmi    dol_ask_speed
  31.     cmpi.l    #SPEED_MAX,d0
  32.     bhi    dol_err
  33.  
  34.     tst.l    _vdisp(a6)
  35.     bmi    dol_ask_vdisp
  36.  
  37.  
  38.  
  39.     moveq.l    #4,d3
  40.     sub.w    d0,d3    * d3.w = vdisp 待ち回数－１
  41.  
  42.     movea.l    _source_ptr(a6),a2    * a2.l = 転送元アドレス・その１
  43.     movea.l    _dest_ptr(a6),a3    * a3.l = 転送先アドレス・その１
  44.  
  45.     moveq.l    #8-1,d7    * d7.w = ループ回数－１
  46. dol_loop_y:
  47.     moveq.l    #8-1,d6    * d6.w = ループ回数－１
  48. dol_loop_x:
  49.     move.w    d3,d0
  50. @@:    bsr    vdisp
  51.     dbra    d0,@b
  52.  
  53.     movea.l    a2,a0
  54.     movea.l    a3,a1
  55.  
  56.     moveq.l    #64-1,d5
  57. dol_loop_y2:
  58.     moveq.l    #64/16-1,d4
  59. dol_loop_x2:
  60.     move.w    (a0),(a1)
  61.     move.w    16*1(a0),16*1(a1)
  62.     move.w    16*2(a0),16*2(a1)
  63.     move.w    16*3(a0),16*3(a1)
  64.     move.w    16*4(a0),16*4(a1)
  65.     move.w    16*5(a0),16*5(a1)
  66.     move.w    16*6(a0),16*6(a1)
  67.     move.w    16*7(a0),16*7(a1)
  68.     move.w    16*8(a0),16*8(a1)
  69.     move.w    16*9(a0),16*9(a1)
  70.     move.w    16*10(a0),16*10(a1)
  71.     move.w    16*11(a0),16*11(a1)
  72.     move.w    16*12(a0),16*12(a1)
  73.     move.w    16*13(a0),16*13(a1)
  74.     move.w    16*14(a0),16*14(a1)
  75.     move.w    16*15(a0),16*15(a1)
  76.     lea.l    16*16(a0),a0
  77.     lea.l    16*16(a1),a1
  78.     dbra    d4,dol_loop_x2
  79.  
  80.     lea.l    7*512*2(a0),a0
  81.     lea.l    7*512*2(a1),a1
  82.     dbra    d5,dol_loop_y2
  83.  
  84.     addq.w    #2,a2
  85.     addq.w    #2,a3
  86.     dbra    d6,dol_loop_x
  87.  
  88.     adda.w    #(512-8)*2,a2
  89.     adda.w    #(512-8)*2,a3
  90.     dbra    d7,dol_loop_y
  91.  
  92.     moveq.l    #0,d0
  93. dol_rts:
  94.     movem.l    (sp)+,d1-d7/a0-a5
  95.     unlk    a6
  96.     rts
  97.  
  98.  
  99. ****    ****
  100. vdisp:
  101.     movem.l    a0,-(sp)
  102.     move.l    _vdisp(a6),a0
  103.     jsr    (a0)
  104.     movem.l    (sp)+,a0
  105.     rts
  106.  
  107.  
  108. ****    ****
  109. dol_err:
  110.     moveq.l    #-1,d0
  111.     bra    dol_rts
  112.  
  113.  
  114. ****    ****
  115. dol_ask_speed:
  116.     moveq.l    #SPEED_MAX,d0
  117.     bra    dol_rts
  118.  
  119.  
  120. ****    ****
  121. dol_ask_vdisp:
  122.     move.l    _speed(a6),d0
  123.     lea.l    ask_vdisp_table(pc),a0
  124.     add.w    d0,d0
  125.     move.w    (a0,d0.w),d0
  126.     bra    dol_rts
  127.  
  128. ask_vdisp_table:
  129.     .dc.w    64*5,64*4,64*3,64*2,64*1
  130.